永磁体磁场分布的例子

q6667911

一个永磁体磁场分布的例子
*go,:start
:start          !利用这个可以让ansys有选择性的读取输入文件
!JPGPRF,500,100,1             ! MACRO TO SET PREFS FOR JPEG PLOTS
/PREP7
emunit,mks        !定义电磁单位为国际标准单位，即μ0=4 Pi e-7 henries/meter

!********************************************
! 定义单元类型*
!********************************************
ET,53,PLANE53                  ! Define PLANE 53 as element type
ET,9,INFIN9        !无限外界（注意：系统原点一定不能在infin9类型的节点上）
!********************************************
! 定义材料*
!********************************************
MP,MURX,1,1         !Define material properties (permeability)    !定义空气（磁导率=1）

HC=895000                 ! Coercive force!表示矫顽力    有的地方为895000
TB,BH,2,,30
TBPT,, 130.000000 , 0.100000000
TBPT,, 170.000000 , 0.200000000
TBPT,, 197.000000 , 0.300000000
TBPT,, 218.000000 , 0.400000000
TBPT,, 250.000000 , 0.500000000
TBPT,, 290.000000 , 0.600000000
TBPT,, 338.000000 , 0.700000000
TBPT,, 400.000000 , 0.800000000
TBPT,, 472.000000 , 0.900000000
TBPT,, 570.000000 , 1.00000000
TBPT,, 682.000000 , 1.10000000
TBPT,, 810.000000 , 1.20000000
TBPT,, 975.000000 , 1.30000000
TBPT,, 1600.00000 , 1.40000000
TBPT,, 2520.00000 , 1.50000000
TBPT,, 3520.00000 , 1.60000000
TBPT,, 4760.00000 , 1.70000000
TBPT,, 8300.00000 , 1.80000000
TBPT,, 12000.0000 , 1.90000000
TBPT,, 17000.0000 , 2.00000000
TBPT,, 23000.0000 , 2.10000000
TBPT,, 32000.0000 , 2.20000000
TBPT,, 42500.0000 , 2.30000000
TBPT,, 44500.0000 , 2.32000000
TBPT,, 48200.0000 , 2.35000000
TBPT,, 52200.0000 , 2.37000000
TBPLOT,BH,2,,,
/IMAGE,SAVE,BH2,JPEG       !将材料2的B-H曲线存储成bh2.jpg
mp,mgxx,2,0          !对于永磁铁，必须定义mgxx（或mgyy）!!!!
mp,mgyy,2,hc

!********************************************
!* 建立模型*
!********************************************
/PNUM,AREA,1          !定义显示模式

wall=20
hall=10
w1=4
h1=2
!x1=(wall-w1)/2
!x2=x1+w1
!y1=(hall-h1)/2
!y2=y1+h1
!rectng,0,wall,0,hall
!rectng,x1,x2,y1,y2
rectng,-wall/2,wall/2,-hall/2,hall/2
rectng,-w1/2,w1/2,-h1/2,h1/2
aovlap,all
numcmp,area          !将生成的面重新编号
aplot

!/eof        !配合前面的:start使用

!********************************************
!建立材料属性
!********************************************
asel,s,area,,1    !选择中间的磁铁
aatt,2
asel,s,area,,2    !选择周围的空气
aatt,1      



!********************************************
!建立单元类型，并划分网格
!********************************************
asel,all
type,53
lsel,s,line,,1,4        !选择所有的无限外边界
type,9          !设定为infin9单元
lesize,all,,,30        !划分为30等份
lmesh,all          !开始划分
lsel,s,line,,5,8   
lesize,all,,,20      !将磁铁边界的每条边分成20等份
asel,all
amesh,all

!********************************************
!建立载荷
!********************************************
ESEL,ALL
NSEL,EXT
D,ALL,AZ,0

!********************************************
!求解
!********************************************
ALLSEL,ALL
MAGSOLV

!********************************************
!后处理
!********************************************
FINISH  
/POST1
PLF2D,27,0,10,1        !显示磁力线

exiaojianghu

还是APDL好使啊